Augmented BNF for Syntax Specifications: ABNF

The name of a rule is simply the name itself, that is, a sequence of characters, beginning with an alphabetic character, and followed by a combination of alphabetics, digits, and hyphens (dashes).¶

NOTE:

 

Rule names are case insensitive.

The names <rulename>, <Rulename>, <RULENAME>, and <rUlENamE> all refer to the same rule.¶

Unlike original BNF, angle brackets ("<", ">") are not required. However, angle brackets may be used around a rule name whenever their presence facilitates in discerning the use of a rule name. This is typically restricted to rule name references in free-form prose, or to distinguish partial rules that combine into a string not separated by white space, such as shown in the discussion about repetition, below.¶

where <name> is the name of the rule, <elements> is one or more rule names or terminal specifications, and <crlf> is the end-of-line indicator (carriage return followed by line feed). The equal sign separates the name from the definition of the rule. The elements form a sequence of one or more rule names and/or value definitions, combined according to the various operators defined in this document, such as alternative and repetition.¶

For visual ease, rule definitions are left aligned. When a rule requires multiple lines, the continuation lines are indented. The left alignment and indentation are relative to the first lines of the ABNF rules and need not match the left margin of the document.¶

Rules resolve into a string of terminal values, sometimes called characters. In ABNF, a character is merely a non-negative integer. In certain contexts, a specific mapping (encoding) of values into a character set (such as ASCII) will be specified.¶

Terminals are specified by one or more numeric characters, with the base interpretation of those characters indicated explicitly. The following bases are currently defined:

      b           =  binary

      d           =  decimal

      x           =  hexadecimal 

Hence:

      CR          =  %d13

      CR          =  %x0D

respectively specify the decimal and hexadecimal representation of [US-ASCII] for carriage return.

A concatenated string of such values is specified compactly, using a period (".") to indicate a separation of characters within that value. Hence:

      CRLF        =  %d13.10 

ABNF permits the specification of literal text strings directly, enclosed in quotation marks. Hence:

      command     =  "command string" 

Literal text strings are interpreted as a concatenated set of printable characters.¶

NOTE:

 

ABNF strings are case insensitive and the character set for these strings is US-ASCII.

Hence:

      rulename = "abc" 

and:

      rulename = "aBc" 

will match "abc", "Abc", "aBc", "abC", "ABc", "aBC", "AbC", and "ABC".

• To specify a rule that is case sensitive, specify the characters individually.

For example:

      rulename    =  %d97 %d98 %d99

or

      rulename    =  %d97.98.99

will match only the string that comprises only the lowercase characters, abc.

External representations of terminal value characters will vary according to constraints in the storage or transmission environment. Hence, the same ABNF-based grammar may have multiple external encodings, such as one for a 7-bit US-ASCII environment, another for a binary octet environment, and still a different one when 16-bit Unicode is used. Encoding details are beyond the scope of ABNF, although Appendix B provides definitions for a 7-bit US-ASCII environment as has been common to much of the Internet.¶

By separating external encoding from the syntax, it is intended that alternate encoding environments can be used for the same syntax.¶

So that the rule <mumble> matches the lowercase string "aba".¶

Linear white space: Concatenation is at the core of the ABNF parsing model. A string of contiguous characters (values) is parsed according to the rules defined in ABNF. For Internet specifications, there is some history of permitting linear white space (space and horizontal tab) to be freely and implicitly interspersed around major constructs, such as delimiting special characters or atomic strings.¶

NOTE: ¶

• This specification for ABNF does not provide for implicit specification of linear white space.

Any grammar that wishes to permit linear white space around delimiters or string segments must specify it explicitly. It is often useful to provide for such white space in "core" rules that are then used variously among higher-level rules. The "core" rules might be formed into a lexical analyzer or simply be part of the main ruleset.¶

Elements separated by a forward slash ("/") are alternatives. Therefore,¶

      foo / bar  

will accept <foo> or <bar>.

NOTE:

 

A quoted string containing alphabetic characters is a special form for specifying alternative characters and is interpreted as a non-terminal representing the set of combinatorial strings with the contained characters, in the specified order but with any mixture of upper- and lowercase.

So that the ruleset

      ruleset     =  alt1 / alt2

      ruleset     =/ alt3

      ruleset     =/ alt4 / alt5 

is the same as specifying

      ruleset     =  alt1 / alt2 / alt3 / alt4 / alt5 

A range of alternative numeric values can be specified compactly, using a dash ("-") to indicate the range of alternative values. Hence:

      DIGIT       =  %x30-39 

is equivalent to:

      DIGIT       =  "0" / "1" / "2" / "3" / "4" / "5" / "6" /

                     "7" / "8" / "9" 

Concatenated numeric values and numeric value ranges cannot be specified in the same string. A numeric value may use the dotted notation for concatenation or it may use the dash notation to specify one value range. Hence, to specify one printable character between end-of-line sequences, the specification could be:

      char-line = %x0D.0A %x20-7E %x0D.0A 

Elements enclosed in parentheses are treated as a single element, whose contents are strictly ordered. Thus,

      elem (foo / bar) blat

matches (elem foo blat) or (elem bar blat), and

      elem foo / bar blat

matches (elem foo) or (bar blat).

NOTE:

 

It is strongly advised that grouping notation be used, rather than relying on the proper reading of "bare" alternations, when alternatives consist of multiple rule names or literals.

Hence, it is recommended that the following form be used:

     (elem foo) / (bar blat) 

It will avoid misinterpretation by casual readers.

The sequence group notation is also used within free text to set off an element sequence from the prose.¶

The operator "*" preceding an element indicates repetition. The full form is:

      <a>*<b>element

where <a> and <b> are optional decimal values, indicating at least <a> and at most <b> occurrences of the element.

Default values are 0 and infinity so that *<element> allows any number, including zero; 1*<element> requires at least one; 3*3<element> allows exactly 3; and 1*2<element> allows one or two.¶

A rule of the form:

      <n>element 

is equivalent to

      <n>*<n>element 

That is, exactly <n> occurrences of <element>. Thus, 2DIGIT is a 2-digit number, and 3ALPHA is a string of three alphabetic characters.¶

Square brackets enclose an optional element sequence:

      [foo bar] 

is equivalent to

      *1(foo bar). 

A semicolon starts a comment that continues to the end of line. This is a simple way of including useful notes in parallel with the specifications.¶

The various mechanisms described above have the following precedence, from highest (binding tightest) at the top, to lowest (loosest) at the bottom: ¶

• Rule name, prose-val, Terminal value
• Comment
• Value range
• Repetition
• Grouping, Optional
• Concatenation
• Alternative

Use of the alternative operator, freely mixed with concatenations, can be confusing.¶

• Again, it is recommended that the grouping operator be used to make explicit concatenation groups.

6.1. Normative References

[US-ASCII]

American National Standards Institute, “Coded Character Set -- 7-bit American Standard Code for Information Interchange”, ANSI X3.4, 1986.

6.2. Informative References

[RFC733]

Crocker, D., Vittal, J., Pogran, K., and D. Henderson, “Standard for the format of ARPA network text messages”, RFC 733, November 1977.

[RFC822]

Crocker, D., “Standard for the format of ARPA Internet text messages”, STD 11, RFC 822, August 1982.

Certain basic rules are in uppercase, such as SP, HTAB, CRLF, DIGIT, ALPHA, etc.¶

Externally, data are represented as "network virtual ASCII" (namely, 7-bit US-ASCII in an 8-bit field), with the high (8th) bit set to zero. A string of values is in "network byte order", in which the higher-valued bytes are represented on the left-hand side and are sent over the network first.¶