Network Working GroupJ. Reschke
Internet-Draftgreenbytes
Intended status: Standards TrackOctober 10, 2009
Expires: April 13, 2010

Application of RFC 2231 Encoding to Hypertext Transfer Protocol (HTTP) Headers
draft-reschke-rfc2231-in-http-05

Status of this Memo

This Internet-Draft is submitted to IETF in full conformance with the provisions of BCP 78 and BCP 79.

Internet-Drafts are working documents of the Internet Engineering Task Force (IETF), its areas, and its working groups. Note that other groups may also distribute working documents as Internet-Drafts.

Internet-Drafts are draft documents valid for a maximum of six months and may be updated, replaced, or obsoleted by other documents at any time. It is inappropriate to use Internet-Drafts as reference material or to cite them other than as “work in progress”.

The list of current Internet-Drafts can be accessed at http://www.ietf.org/ietf/1id-abstracts.txt.

The list of Internet-Draft Shadow Directories can be accessed at http://www.ietf.org/shadow.html.

This Internet-Draft will expire on April 13, 2010.

Copyright Notice

Copyright © 2009 IETF Trust and the persons identified as the document authors. All rights reserved.

This document is subject to BCP 78 and the IETF Trust's Legal Provisions Relating to IETF Documents in effect on the date of publication of this document (http://trustee.ietf.org/license-info). Please review these documents carefully, as they describe your rights and restrictions with respect to this document.

Abstract

By default, message header parameters in Hypertext Transfer Protocol (HTTP) messages can not carry characters outside the ISO-8859-1 character set. RFC 2231 defines an escaping mechanism for use in Multipurpose Internet Mail Extensions (MIME) headers. This document specifies a profile of that encoding suitable for use in HTTP.

Editorial Note (To be removed by RFC Editor before publication)

There are multiple HTTP headers that already use RFC 2231 encoding in practice (Content-Disposition) or might use it in the future (Link). The purpose of this document is to provide a single place where the generic aspects of RFC 2231 encoding in HTTP headers are defined.

Distribution of this document is unlimited. Although this is not a work item of the HTTPbis Working Group, comments should be sent to the Hypertext Transfer Protocol (HTTP) mailing list at ietf-http-wg@w3.org, which may be joined by sending a message with subject "subscribe" to ietf-http-wg-request@w3.org.

Discussions of the HTTPbis Working Group are archived at <http://lists.w3.org/Archives/Public/ietf-http-wg/>.

XML versions, latest edits and the issues list for this document are available from <http://greenbytes.de/tech/webdav/#draft-reschke-rfc2231-in-http>. A collection of test cases is available at <http://greenbytes.de/tech/tc2231/>.


Table of Contents

Issues list

IdTypeStatusDateRaised By
badseqeditclosed2009-10-06julian.reschke@greenbytes.de
tokenquotcharsetchangeclosed2009-10-05julian.reschke@greenbytes.de
editeditopen2009-04-17julian.reschke@greenbytes.de
 I  edit   (type: edit, status: open)
julian.reschke@greenbytes.de2009-04-17 Umbrella issue for editorial fixes/enhancements.
Associated changes in this document: A.1, A.

1. Introduction

By default, message header parameters in HTTP ([RFC2616]) messages can not carry characters outside the ISO-8859-1 character set ([ISO-8859-1]). RFC 2231 ([RFC2231]) defines an escaping mechanism for use in MIME headers. This document specifies a profile of that encoding for use in HTTP.

2. Notational Conventions

The key words "MUST", "MUST NOT", "REQUIRED", "SHALL", "SHALL NOT", "SHOULD", "SHOULD NOT", "RECOMMENDED", "MAY", and "OPTIONAL" in this document are to be interpreted as described in [RFC2119].

This specification uses the ABNF (Augmented Backus-Naur Form) notation defined in [RFC5234]. The following core rules are included by reference, as defined in [RFC5234], Appendix B.1: ALPHA (letters), DIGIT (decimal 0-9), HEXDIG (hexadecimal 0-9/A-F/a-f) and LWSP (linear white space).

Note that this specification uses the term "character set" for consistency with other IETF specifications such as RFC 2277 (see [RFC2277], Section 3). A more accurate term would be "character encoding" (a mapping of code points to octet sequences).

3. A Profile of RFC 2231 for Use in HTTP

RFC 2231 defines several extensions to MIME. The sections below discuss if and how they apply to HTTP.

In short:

3.1 Parameter Continuations

Section 3 of [RFC2231] defines a mechanism that deals with the length limitations that apply to MIME headers. These limitations do not apply to HTTP ([RFC2616], Section 19.4.7).

Thus in HTTP, senders MUST NOT use parameter continuations, and therefore recipients do not need to support them.

3.2 Parameter Value Character Set and Language Information

Section 4 of [RFC2231] specifies how to embed language information into parameter values, and also how to encode non-ASCII characters, dealing with restrictions both in MIME and HTTP header parameters.

However, RFC 2231 does not specify a mandatory-to-implement character set, making it hard for senders to decide which character set to use. Thus, recipients implementing this specification MUST support the character sets "ISO-8859-1" [ISO-8859-1] and "UTF-8" [RFC3629].

Furthermore, RFC 2231 allows leaving out the character set information. The profile defined by this specification does not allow that.

The syntax for parameters is defined in Section 3.6 of [RFC2616] (with RFC 2616 implied LWS translated to RFC 5234 LWSP):

  parameter     = attribute LWSP "=" LWSP value
  attribute     = token
  value         = token / quoted-string

  quoted-string = <quoted-string, defined in [RFC2616], Section 2.2>
  token         = <token, defined in [RFC2616], Section 2.2>

This specification extends the grammar to:

  parameter     = reg-parameter / ext-parameter
   
  reg-parameter = attribute LWSP "=" LWSP value

  ext-parameter = attribute "*" LWSP "=" LWSP ext-value

  ext-value     = charset  "'" [ language ] "'" value-chars
                ; extended-initial-value,
                ; defined in [RFC2231], Section 7

  charset       = "UTF-8" / "ISO-8859-1" /  I ext-charset

  ext-charset   = token ; see IANA charset registry
                ; (<http://www.iana.org/assignments/character-sets>)mime-charset
                
  mime-charset  = 1*mime-charsetc
  mime-charsetc = ALPHA / DIGIT
                / "!" / "#" / "$" / "%" / "&"
                / "+" / "-" / "^" / "_" / "`"
                / "{" / "}" / "~"
                ; as <mime-charset> in Section 2.3 of [RFC2978]
                ; except that the single quote is not included
  
  language      = <Language-Tag, defined in [RFC5646], Section 2.1>
  
  value-chars   = *( pct-encoded / attr-char )

  pct-encoded   = "%" HEXDIG HEXDIG
                ; see [RFC3986], Section 2.1

  attr-char     = ALPHA / DIGIT
                / "-" / "." / "_" / "~" / ":"
                / "!" / "$" / "&" / "+"
 I  tokenquotcharset   (type: change, status: closed)
julian.reschke@greenbytes.de2009-10-05 token can contain single quotes. ABNF is ambiguous for charset in ext-value.
duerst@it.aoyama.ac.jp2009-10-06 (points out that Section 2.3 of RFC 2978 doesn't allow the single quote) - <http://lists.w3.org/Archives/Public/ietf-http-wg/2009OctDec/0014.html>.
Associated changes in this document: 3.2, 3.2, 7.

Thus, a parameter is either regular parameter (reg-parameter), as previously defined in Section 3.6 of [RFC2616], or an extended parameter (ext-parameter).

Extended parameters are those where the left hand side of the assignment ends with an asterisk character.

The value part of an extended parameter (ext-value) is a token that consists of three parts: the REQUIRED character set name (charset), the OPTIONAL language information (language), and a character sequence representing the actual value (value-chars), separated by single quote characters. Note that both character set names and language tags are restricted to the US-ASCII character set, and are matched case-insensitively (see [RFC2978], Section 2.3 and [RFC5646], Section 2.1.1).

Inside the value part, characters not contained in attr-char are encoded into an octet sequence using the specified character set. That octet sequence then is percent-encoded as specified in Section 2.1 of [RFC3986].

Producers MUST NOT use character sets other than "UTF-8" ([RFC3629]) or ISO-8859-1 ([ISO-8859-1]). Extension character sets (ext-charset) are reserved for future use.

 I  badseq   (type: edit, status: closed)
julian.reschke@greenbytes.de2009-10-06 Mention recipient handling for broken encoded sequences.
2009-10-06Resolution: Done.
Associated changes in this document: 3.2.

Note: recipients should be prepared to handle encoding errors, such as malformed or incomplete percent escape sequences, or non-decodable octet sequences, in a robust manner. This specification does not mandate any specific behavior, for instance the following strategies are all acceptable:

  • ignoring the parameter,
  • stripping a non-decodable octet sequence,
  • substituting a non-decodable octet sequence by a replacement character, such as the Unicode character U+FFFD (Replacement Character).

Note: the <mime-charset> ABNF defined here differs from the one in Section 2.3 of [RFC2978] in that it does not allow the single quote character. In practice, no character set names using that character have been registered at the time of this writing.

3.2.1 Examples

Non-extended notation, using "token":

  foo: bar; title=Economy

Non-extended notation, using "quoted-string":

  foo: bar; title="US-$ rates"

Extended notation, using the unicode character U+00A3 (POUND SIGN):

  foo: bar; title*=iso-8859-1'en'%A3%20rates

Note: the Unicode pound sign character U+00A3 was encoded using ISO-8859-1 into the single octet A3, then percent-encoded. Also note that the space character was encoded as %20, as it is not contained in attr-char.

Extended notation, using the unicode characters U+00A3 (POUND SIGN) and U+20AC (EURO SIGN):

  foo: bar; title*=UTF-8''%c2%a3%20and%20%e2%82%ac%20rates

Note: the unicode pound sign character U+00A3 was encoded using UTF-8 into the octet sequence C2 A3, then percent-encoded. Likewise, the unicode euro sign character U+20AC was encoded into the octet sequence E2 82 AC, then percent-encoded. Also note that HEXDIG allows both lower-case and upper-case character, so recipients must understand both, and that the language information is optional, while the character set is not.

3.3 Language specification in Encoded Words

Section 5 of [RFC2231] extends the encoding defined in [RFC2047] to also support language specification in encoded words. Although the HTTP/1.1 specification does refer to RFC 2047 ([RFC2616], Section 2.2), it's not clear to which header field exactly it applies, and whether it is implemented in practice (see <http://tools.ietf.org/wg/httpbis/trac/ticket/111> for details).

Thus, the RFC 2231 profile defined by this specification does not include this feature.

4. Guidelines for Usage in HTTP Header Definitions

Specifications of HTTP headers that use the extensions defined in Section 3.2 should clearly state that. A simple way to achieve this is to normatively reference this specification, and to include the ext-value production into the ABNF for that header.

For instance:

  foo-header  = "foo" LWSP ":" LWSP token ";" LWSP title-param
  title-param = "title" LWSP "=" LWSP value
              / "title*" LWSP "=" LWSP ext-value
  ext-value   = <see RFCxxxx, Section 3.2>

[rfcno: Note to RFC Editor: in the figure above, please replace "xxxx" by the RFC number assigned to this specification.]

4.1 When to Use the Extension

Section 4.2 of [RFC2277] requires that protocol elements containing text can carry language information. Thus, the ext-value production should always be used when the parameter value is of textual nature.

Furthermore, the extension should also be used whenever the parameter value needs to carry characters not present in the US-ASCII ([USASCII]) character set (note that it would be unacceptable to define a new parameter that would be restricted to a subset of the Unicode character set).

4.2 Error Handling

Header specifications that include parameters should also specify whether same-named parameters can occur multiple times. If repetitions are not allowed (and this is believed to be the common case), the specification should state whether regular or the extended syntax takes precedence. In the latter case, this could be used by producers to use both formats without breaking recipients that do not understand the syntax.

Example:

  foo: bar; title="EURO exchange rates";
            title*=utf-8''%e2%82%ac%20exchange%20rates

In this case, the sender provides an ASCII version of the title for legacy recipients, but also includes an internationalized version for recipients understanding this specification -- the latter obviously should prefer the new syntax over the old one.

Note: at the time of this writing, many implementations failed to ignore the form they do not understand, or prioritize the ASCII form although the extended syntax was present.

4.3 Using Multiple Instances for Internationalization

It is expected that in many cases, internationalization of parameters in response headers is implemented using server driven content negotiation ([RFC2616], Section 12.1) using the Accept-Language header ([RFC2616], Section 14.4). However, the format described in this specification also allows to use multiple instances providing multiple languages in a single header. Specifications that want to take advantage of this should clearly specify the expected processing by the recipient.

Example:

  foo: bar; title*=utf-8'en'Document%20Title;
            title*=utf-8'de'Titel%20des%20Dokuments

5. Security Considerations

This document does not discuss security issues and is not believed to raise any security issues not already endemic in HTTP.

6. IANA Considerations

There are no IANA Considerations related to this specification.

7. Acknowledgements

Thanks to  I Martin Duerst and Frank Ellermann for help figuring out ABNF details, and to Roar Lauritzsen for implementer's feedback.

8. References

8.1 Normative References

[ISO-8859-1]International Organization for Standardization, “Information technology -- 8-bit single-byte coded graphic character sets -- Part 1: Latin alphabet No. 1”, ISO/IEC 8859-1:1998, 1998.
[RFC2119]Bradner, S., “Key words for use in RFCs to Indicate Requirement Levels”, BCP 14, RFC 2119, March 1997.
[RFC2616]Fielding, R., Gettys, J., Mogul, J., Frystyk, H., Masinter, L., Leach, P., and T. Berners-Lee, “Hypertext Transfer Protocol -- HTTP/1.1”, RFC 2616, June 1999.
[RFC3629]Yergeau, F., “UTF-8, a transformation format of ISO 10646”, RFC 3629, STD 63, November 2003.
[RFC5234]Crocker, D., Ed. and P. Overell, “Augmented BNF for Syntax Specifications: ABNF”, STD 68, RFC 5234, January 2008.
[RFC5646]Phillips, A., Ed. and M. Davis, Ed., “Tags for Identifying Languages”, BCP 47, RFC 5646, September 2009.

8.2 Informative References

[RFC2047]Moore, K., “MIME (Multipurpose Internet Mail Extensions) Part Three: Message Header Extensions for Non-ASCII Text”, RFC 2047, November 1996.
[RFC2231]Freed, N. and K. Moore, “MIME Parameter Value and Encoded Word Extensions: Character Sets, Languages, and Continuations”, RFC 2231, November 1997.
[RFC2277]Alvestrand, H., “IETF Policy on Character Sets and Languages”, BCP 18, RFC 2277, January 1998.
[RFC2978]Freed, N. and J. Postel, “IANA Charset Registration Procedures”, BCP 19, RFC 2978, October 2000.
[RFC3986]Berners-Lee, T., Fielding, R., and L. Masinter, “Uniform Resource Identifier (URI): Generic Syntax”, RFC 3986, STD 66, January 2005.
[USASCII]American National Standards Institute, “Coded Character Set -- 7-bit American Standard Code for Information Interchange”, ANSI X3.4, 1986.

A. Change Log (to be removed by RFC Editor before publication)

A.1 Since draft-reschke-rfc2231-in-http-00

Use RFC5234-style ABNF, closer to the one used in RFC 2231.

Make RFC 2231 dependency informative, so this specification can evolve independ I aently.

Explain the ABNF in prose.

A.2 Since draft-reschke-rfc2231-in-http-01

Remove unneeded RFC5137 notation (code point vs character).

A.3 Since draft-reschke-rfc2231-in-http-02

And and resolve issues "charset", "repeats" and "rfc4646".

A.4 Since draft-reschke-rfc2231-in-http-03

And and resolve issue "charsetmatch".

 I  

A.5 Since draft-reschke-rfc2231-in-http-04

Add and resolve issues "badseq" and "tokenquotcharset".

Author's Address

Julian F. Reschke
greenbytes GmbH
Hafenweg 16
Muenster, NW 48155
Germany
EMail: julian.reschke@greenbytes.de
URI: http://greenbytes.de/tech/webdav/